AppleScript - automatické spuštění po startu Macu

[Sandra]

Zdravím, potřebovala bych poradit, jak po startu Macu automaticky spustit script vytvořený v AppleScriptu. Jde mi o připojení disků z NASu bez otravného otevírání oken ve Finderu. Script mi funguje, když ho spustím ručně, tak vykoná co má, ale nemůžu přijít na to, jak ho spustit po startu Macu. Když jsem dala script do "Přihlášení" v "Předvolby systému", tak mi to ten script otevřelo v Editoru scriptů, což není to, co chci. Díky moc.

[Zeggjk]

Dobrý den, máte script , soubor s extenzí scpt a v něm něco takového: mount volume "smb://" & IP_address & "/" & Share & "/" & MainFolder ?

Tak si otevřete editor scriptů, v něm ten váš spubor a dejte nabídku exportovat.. a uložte to do formátu souboru: Aplikace. Zvolte kam se to má uložit. Soubor bude mít extenzi app. No a tento soubor si dejte do nastavení Uživatelé a skupiny - Přihlášení. Pro inspiraci přikládám kód svého scriptu, který mám exportován do app, mám ho přidán do "Po přihlášení se automaticky otevřou tyto položky". Jen na mě vyskakuje hláška, že disk xyz je připojen, ale to jen stačí smazat na konci tu sekci tell application Finder po end tell kde je display dialog "Disk " & TestMount & " je připojen"

Kód: Vybrat vše

try
	
	-->> Definice proměnných ----------------------------------------<<--
	(* Nadefinuj IP adresu nebo DNS název tvého souborového serveru *)
	set IP_address to "10.10.64.60"
	
	(* Nadefinuj Share, ke kterému se chceš připojit *)
	set Share to "Data"
	
	
	(*Pokud chceš připojit až nějaký adresář, např. \\server\share\mujadresar, nadefinuj i MainFolder..
	set MainFolder to "mujdresar" 
	POZOR i když se nechceč připojit do adresáře, MainFolder musí být vždy nastaven takto: set MainFolder  to "" *)
	set MainFolder to ""
	
	(* Nastavení času kdy skript čeká z důvodu navázání spojení přes wifi atp. 
	definován je 60 sec, pokud je připojení kabelem, může se čas snížit*)
	delay 10
	--->> ---------------------------------------------------------------------------- <<--
	
	
	set IP_Valid to true
	set Disk_OK to false
	
	try
		do shell script ("ping -c 2 " & IP_address)
	on error
		set IP_Valid to false
	end try
	
	if MainFolder = "" then
		set TestMount to Share
	else
		set TestMount to MainFolder
	end if
	
	
	if IP_Valid then
		tell application "Finder"
			if not (disk TestMount exists) then
				mount volume "smb://" & IP_address & "/" & Share & "/" & MainFolder
			end if
			
		end tell
		
		delay 5
		
		tell application "Finder"
			if disk TestMount exists then
				display dialog "Disk " & TestMount & " je připojen"
			end if
		end tell
		
	end if
	
on error
	return 0
end try

[rony]

ja som urobil toto

otvoril som automator, vlozil som applescript tam a nasledne som vytvoril “app”. tuto app som dal do login items.

[Sandra]

Dobrý den, máte script , soubor s extenzí scpt a v něm něco takového: mount volume "smb://" & IP_address & "/" & Share & "/" & MainFolder ?

Tak si otevřete editor scriptů, v něm ten váš spubor a dejte nabídku exportovat.. a uložte to do formátu souboru: Aplikace. Zvolte kam se to má uložit. Soubor bude mít extenzi app. No a tento soubor si dejte do nastavení Uživatelé a skupiny - Přihlášení. Pro inspiraci přikládám kód svého scriptu, který mám exportován do app, mám ho přidán do "Po přihlášení se automaticky otevřou tyto položky". Jen na mě vyskakuje hláška, že disk xyz je připojen, ale to jen stačí smazat na konci tu sekci tell application Finder po end tell kde je display dialog "Disk " & TestMount & " je připojen"

To je přesně ono, takže export, moc děkuju